To answer this question well really requires a thorough understanding of GNU autotools, which I don't have: nevertheless I hope these comments will help.

The configure script for a particular build is generated from its configure.ac file using autoconf. In turn, configure.ac uses standard macros to test for the presence of specified components. In this particular case, configure.ac specifies an AC_CHECK_LIB test for the GSL library as

  AC_CHECK_LIB(gsl, gsl_sf_bessel_Jn, [],

        [AC_MSG_WARN([Missing GNU GSL library...Bessel-function field initialization will not be supported.])])

The syntax of an AC_CHECK_LIB is

AC_CHECK_LIB (library, function, [action-if-found], [action-if-not-found], [other-libraries])

and the actual mechanism by which the check is performed is by creating a minimal test program (conftest) for the specified function gsl_sf_bessel_Jn in library libgsl, and attempting to link it using the default build tools. Such a minimal program might look something like

char gsl_sf_bessel_Jn();



int main() { return gsl_sf_bessel_Jn(); return 0; }

Note that the dummy prototype char gsl_sf_bessel_Jn() may bear no relation to the return type or argument list of the actual function - we never attempt to run the program, we just wish to know whether it links (i.e. whether the linker is able to resolve library references). We can see how this works if we create such a source file ourselves:

$ cat > conftest.c

char gsl_sf_bessel_Jn();



int main() { return gsl_sf_bessel_Jn(); return 0; }

Ctrl+D

As expected, if we try to run it without linking the GSL library, we get an error

$ gcc conftest.c

/tmp/ccWqFraS.o: In function `main':

conftest.c:(.text+0xa): undefined reference to `gsl_sf_bessel_Jn'

collect2: error: ld returned 1 exit status

However even if we explicitly link libgsl we find

$ gcc conftest.c -lgsl

/usr/lib/gcc/x86_64-linux-gnu/4.8/../../../../lib/libgsl.so: undefined reference to `cblas_dasum'

/usr/lib/gcc/x86_64-linux-gnu/4.8/../../../../lib/libgsl.so: undefined reference to `cblas_sger'

.

<snip>

.

/usr/lib/gcc/x86_64-linux-gnu/4.8/../../../../lib/libgsl.so: undefined reference to `cblas_zdotu_sub'

collect2: error: ld returned 1 exit status

At this point, it's important to note that the configure script doesn't know why a particular test has failed, only that it has. In this case, it has failed because we didn't link the subordinate libgslcblas library.

This illustrates the importance of the order in which tests are performed: each successful test causes the newly discovered library to be added to the $LIB variable for subsequent tests. Specifically (as noted in the GSL documentation)

It is important to check for libm and libgslcblas before libgsl,
otherwise the tests will fail. Assuming the libraries are found the
output during the configure stage looks like this,

checking for cos in -lm... yes 

checking for cblas_dgemm in -lgslcblas... yes 

checking for gsl_blas_dgemm in -lgsl... yes 

If the library is found then the tests will define the macros
HAVE_LIBGSL, HAVE_LIBGSLCBLAS, HAVE_LIBM and add the options -lgsl
-lgslcblas -lm to the variable LIBS.

The meep source package does check for libgslcblas before libgsl, however the specific check that it does is an AC_CHECK_FUNC rather than an AC_CHECK_LIB

AC_CHECK_FUNC(cblas_cgemm, [], [AC_CHECK_LIB(gslcblas, cblas_cgemm)])

While superficially similar, it appears that AC_CHECK_FUNC does not append the library to $LIBS on success; it appears we can work around this simply by adding an explicit AC_CHECK_LIB for libgslcblas in the configure.ac file

# GNU Scientific Library

AC_CHECK_FUNC(cblas_cgemm, [], [AC_CHECK_LIB(gslcblas, cblas_cgemm)])

AC_CHECK_LIB([gslcblas],[cblas_cgemm])

AC_CHECK_LIB(gsl, gsl_sf_bessel_Jn, [],

   [AC_MSG_WARN([Missing GNU GSL library...Bessel-function field initialization will not be supported.])])

and then running autoconf to regenerate the configure script

$ autoconf

after which running ./configure reports that the the GSL library is indeed found:

$ ./configure --prefix=/usr/local | grep gsl

configure: WARNING: Cannot find latex2html in your path!

configure: WARNING: FFTW needed for MPB

checking for cblas_cgemm in -lgslcblas... yes

checking for gsl_sf_bessel_Jn in -lgsl... yes